Kwadratowa ramka z prądem o natężeniu I, umieszczona w płaszczyźnie z=0. Boki ramki o długościa 𝒶 są równoległe do osi układu, a środek ramki pokrywa się z początkiem układu współrzędnych

rp1={a/2,-a/2+t*a,0};

dl1podt=D[rp1,t]

rp2={a/2-t*a,a/2,0};

dl2podt=D[rp2,t]

rp3={-a/2,a/2-t*a,0};

dl3podt=D[rp3,t]

rp4={-a/2+t*a,-a/2,0};

dl4podt=D[rp4,t]

(*
a=2;plot1=ParametricPlot3D[{rp1,rp2,rp3,rp4},{t,0,1},AxesLabel->{"x","y","z"}];
a=.;
*)

r={x,y,z}

d1=Simplify[Sqrt[(r-rp1).(r-rp1)]]

d2=Simplify[Sqrt[(r-rp2).(r-rp2)]]

d3=Simplify[Sqrt[(r-rp3).(r-rp3)]]

d4=Simplify[Sqrt[(r-rp4).(r-rp4)]]

v1=Simplify[Cross[dl1podt,r-rp1]/d1^3]

v2=Simplify[Cross[dl2podt,r-rp2]/d2^3]

v3=Simplify[Cross[dl3podt,r-rp3]/d3^3]

v4=Simplify[Cross[dl4podt,r-rp4]/d4^3]

v=Simplify[v1+v2+v3+v4,a>0]

(*
ft02=Simplify[Integrate[v,{t,0,1}],Element[t,Reals]&&Element[a,Reals]&&Element[x,Reals]&&Element[y,Reals]&&Element[z,Reals]&&a>0]
*)

ft=Simplify[Integrate[v,t],Element[t,Reals]&&Element[a,Reals]&&Element[x,Reals]&&Element[y,Reals]&&Element[z,Reals]&&a>0];

ft1=Simplify[ft/.{t->1}];

ft0=Simplify[ft/.{t->0}];

ft01=Simplify[ft1-ft0,Element[a,Reals]&&Element[x,Reals]&&Element[y,Reals]&&Element[z,Reals]&&a>0];

B1=ft01/.{a->u*z}

B2=Simplify[Normal[Series[B1,{u,0,2}]]]

B3=Simplify[B2/.{u->a/z}]

(* Ten wynik należy pomnożyć przez mu0*I/(4*Pi) *)

Teraz wyprowadzę analogiczny przybliżony wzór dla dipola elektrycznego !

ClearAll[a,rp1,rp2,r];

rp1={0,0,-L/2}

rp2={0,0,L/2};

r={x,y,z};

E1=k*Q*(r-rp2)/Sqrt[(r-rp2).(r-rp2)]^3-k*Q*(r-rp1)/Sqrt[(r-rp1).(r-rp1)]^3

E2=E1/.{L->w*z}

E3=Simplify[Normal[Series[E2,{w,0,2}]]]

E4=E3/.{w->L/z}