Ilustracja do prawa Ampere’a nr 2

Najpierw liczymy indukcję magnetyczną pochodzącą od obwodu z prądem w kształcie łamanej rozciągającej się między punktami P1 i P2, P2 i P3 oraz P3 i P1.

P1={-1,-3,-12};

P2={1,2,10};

P3={10,10,1};

rp1=P1+(P2-P1)*t

s=Solve[rp1[[3]]==0,t]

rp1z0=rp1/.s[[1]]

Rmin=N[Norm[rp1z0]]

rp2=P2+(P3-P2)*t

rp3=P3+(P1-P3)*t

plot1=ParametricPlot3D[{rp1,rp2,rp3},{t,0,1}];

r={x,y,z}

d1=Simplify[Sqrt[(r-rp1).(r-rp1)]];

dl1podt=D[rp1,t];

v1=Simplify[Cross[dl1podt,r-rp1]/d1^3];

d2=Simplify[Sqrt[(r-rp2).(r-rp2)]];

dl2podt=D[rp2,t];

v2=Simplify[Cross[dl2podt,r-rp2]/d2^3];

d3=Simplify[Sqrt[(r-rp3).(r-rp3)]];

dl3podt=D[rp3,t];

v3=Simplify[Cross[dl3podt,r-rp3]/d3^3];

v=Simplify[v1+v2+v3];

(* ft=Simplify[Integrate[v,t],Element[t,Reals]&&Element[x,Reals]&&Element[y,Reals]&&Element[z,Reals]];*)

ft=Integrate[v,t];

ft1=Simplify[ft/.{t->1}];

ft0=Simplify[ft/.{t->0}];

B=Simplify[ft1-ft0];

Krążenie uprzednio policzonego pola B liczymy po okręgu o promieniu R=1, środku w początku układu współrzędnych i leżącym w płaszczyźnie z=0

rp={R*Cos[t],R*Sin[t],0}

plot2=ParametricPlot3D[rp/.{R->1},{t,0,2*Pi},AxesLabel->{"x","y","z"},PlotStyle->Thick];

Show[plot1,plot2]

dlpodt=D[rp,t]

Brp=B/.{x->R*Cos[t],y->R*Sin[t],z->0};

cc[R_]=Simplify[Brp.dlpodt];

i3[R_]:=NIntegrate[cc[R],{t,0,2*Pi},Method->{"GlobalAdaptive",Method->{"TrapezoidalRule","Points"->5000},"SingularityHandler"->None},WorkingPrecision->16,PrecisionGoal->12]/(4*Pi)

i4[R_]:=NIntegrate[cc[R],{t,0,2*Pi},Method->{"GlobalAdaptive",Method->{"TrapezoidalRule","Points"->5000},"SingularityHandler"->None},WorkingPrecision->18,PrecisionGoal->16]/(4*Pi)

(* Plot[i3[R],{R,1/1000,1}] *)

(* i3[1/100] *)

i3[2/10]

i3[1/2]

i3[1]

i3[20]

Plot[i3[R],{R,2/10,20},PlotPoints->10,PlotRange->{-1/7,8/7}]