Zadanie 
Jednorodny pręt o masie M i długości L leży na gładkiej powierzchni poziomej. Pocisk o masie m lecący poziomo z prędkością v trafia prostopadle w koniec nieruchomego pręta i pozostaje w nim. Obliczyć prędkość kątową ω pręta po zderzeniu. 

Rozwiązanie w nieruchomym inercjalnym układzie
 
Moment pędu LO jest liczony względem początku nieruchomego układu współrzędnych. Na początku dany jest przez pęd cząstki o masie m i parametr zderzenia L/2. Korzystamy z zasady zachowania pędu (w płaszczyźnie poziomej) oraz zachowania składowej momentu pędu prostopadłej do powierzchni z prętem. 

Zakładam, że początek i koniec pręta przed zderzeniem znajdują sie odpowiednio w punktach A(0,L/2) oraz B(0,-L/2). Masa m ma wektor prędkości v równoległy do osi x i uderza w punkt A.

(* składowa z momentu pędu układu przed zderzeniem wzięta z przeciwnym znakiem, bo masa ma porusza się w prawo ! *)

LOpocz=m*v*L/2;

(* pęd całkowity układu *)

P=m*v

(* prędkość środka masy *)

V=P/(m+M)

(* składowa y położenia środka masy *)

ycm=m*L/(2*(m+M))

(* składowa x położenia środka masy *)

xcm=V*t

(* wektor położenia środka masy *)

R={xcm,ycm,0}

(* Składowa z momentu pędu środka masy traktowanego jak cząstka punktowa wzięta z przeciwnym znakiem: LOcm = -(Subscript[(R x P), z])  *)

LOcm=Simplify[-Cross[R,{P,0,0}][[3]]]

(* Moment pędu względem środka masy Lcm po zderzeniu jest liczony jako różnica całkowitego momentu pędu LOpocz i momentu pędu środka masy LOcm *)

Lcm=Simplify[LOpocz-LOcm]

(* Moment pędu Lcm jest iloczynem momentu bezwładności Icm pręta z doklejoną masą względem osi przechodzącej przez środek masy układu i prostopadłej do pręta oraz prędkości kątowej omega  *)

Icm=Simplify[m*(L/2-ycm)^2 +(1/12)*M*L^2+M*ycm^2]

omega=Lcm/Icm

(* Sprawdzenie bilansu energii kinetycznej. W tym procesie energia jest tracona w procesie zlepiania masy m z prętem, więc początkowa energia kinetyczna musi być większa od końcowej energii kinetycznej, niezależnie od wartości mas m i M ! Na początku porusza się tylko masa m *)

Epocz=(1/2)*m*v^2

(* Na końcu mamy ruch postępowy środka masy i ruch obrotowy względem środka masy *)

Ekon=P^2/(2*(m+M))+(1/2)*Icm*omega^2

bilans=FullSimplify[Epocz-Ekon]

Modelowanie nieelastycznego zderzenia punktowej masy z prętem

(* Przykładowe dane liczbowe *)

M=1; (* kg *)

m=1/2; (* kg *)

L=1/2; (* m *)

v=2; (* m/s *)

p0=m*v;

b=L/2-ycm;

t0=-1; (* początek mierzenia czasu: |t0| sekund do zderzenia  *)

(* wektor położenia środka masy układu *)

rcm[t_]:={((m t v)/(m+M)),((L m)/(2 (m+M)))}

cm[t_]:=Line[{rcm[t0],rcm[t]}]

gcm[t_]:=Graphics[{Pink,cm[t]}]

(* położenie górnego (przed obrotem) końca pręta *)

rA[t_]:=If[t<0,{0,L/2},rcm[t]+{b*Sin[omega*t],b*Cos[omega*t]}];

(* położenie dolnego (przed obrotem) końca pręta *)

rB[t_]:=If[t<0,{0,-L/2},rcm[t]+{-(L-b)*Sin[omega*t],-(L-b)*Cos[omega*t]}];

pret[t_]:=Line[{rA[t],rB[t]}];

gpret[t_]:=Graphics[{Thick,Blue,pret[t]}]

(* położenie punktowej masy *)

r1[t_]:=If[t<0,{v*t,L/2},rA[t]];

masa[t_]=Disk[r1[t],1/20];

gmasa[t_]:=Graphics[masa[t]]

Animate[Show[gmasa[t],gpret[t],gcm[t],PlotRange->{{-2.5,5},{-0.6,0.6}},AspectRatio->Automatic],{t,t0,7}]

aaa=Table[Show[gmasa[t],gpret[t],gcm[t],PlotRange->{{-2.5,5},{-0.6,0.6}},AspectRatio->Automatic],{t,t0,8,0.04}];

Export[
 NotebookDirectory[] <> "rod2.gif", aaa];