Zadanie 
Jednorodny pręt o masie M i długości L leży na gładkiej powierzchni poziomej i może obracać się swobodnie wokół pionowej osi, która przechodzi przez jego środek . Pocisk o masie m lecący poziomo z prędkością v trafia prostopadle w koniec nieruchomego pręta i rozprasza się elastycznie pod kątem θ. Obliczyć długość wektora prędkości punktowej masy po zderzeniu (v1) oraz prędkość kątową ω pręta po zderzeniu. 

Rozwiązanie w nieruchomym inercjalnym układzie
 
Moment pędu LO jest liczony względem początku nieruchomego układu współrzędnych. Na początku dany jest przez pęd cząstki o masie m i parametr zderzenia L/2. Korzystamy z zasad zachowania energii kinetycznej oraz zachowania składowej momentu pędu prostopadłej do powierzchni z prętem. 

Zakładam, że początek i koniec pręta przed zderzeniem znajdują się odpowiednio w punktach A(0,L/2) oraz B(0,-L/2). Masa m ma wektor prędkości v równoległy do osi x i uderza w punkt A.

(* składowa z momentu pędu układu przed zderzeniem wzięta z przeciwnym znakiem,bo masa ma porusza się w prawo! *)

LOpocz=m*v*L/2;

(* Wektor położenia vecr1 punktowej masy po zderzeniu (t=0 odpowiada momentowi zderzenia *)

vecr1={0,L/2,0}+t*{v1*Cos[θ],v1*Sin[θ],0};

(* pęd vecp1 punktowej masy po zderzeniu *)

vecp1=m*{v1*Cos[θ],v1*Sin[θ],0};

LOm=Cross[vecr1,vecp1]

(* Moment pędu środka masy pręta po zderzeniu wynosi 0 ! *)

(* Moment bezwładności pręta względem osi przechodzącej przez środek pręta i prostopadłej do pręta *)
Is=(1/12)*M*L^2;

(* Układ równań wynikających z zasady zachowania energii i momentu pędu względem początku nieruchomego układu współrzędnych *)

s=FullSimplify[Solve[{v==v1*Cos[θ]+2*Is*ω/(m*L),v^2==v1^2+Is*ω^2/m},{v1,ω}],m>0&&M>0&&v1>0&&ω>0]

Dimensions[s]

(* Mamy dwa rozwiązania: s[[1]] i s[[2]], jak to bywa w elastycznym rozpraszaniu *)

s[[1]]

s[[2]]

v11=v1/.s[[1]]

ω1=ω/.s[[1]]

v12=v1/.s[[2]]

ω2=ω/.s[[2]]

(* Przykładowe dane liczbowe. Biorę masę m znacznie mniejszą od masy pręta M. *)

M=1/6; (* kg *)

m=1/5; (* kg *)

L=1/2; (* m *)

v=2; (* m/s *)

Is=(1/12)*M*L^2;

Plot[v11,{θ,0,Pi}]

Plot[ω1,{θ,0,Pi}]

Plot[v12,{θ,0,Pi}]

Plot[ω2,{θ,0,Pi}]

Modelowanie elastycznego zderzenia punktowej masy z prętem

θ=Pi/8; (* kąt rozproszenia punktowej masy m *)

N[θ] (* kąt rozproszenia punktowej masy m *)

t0=-1; (* początek mierzenia czasu: |t0| sekund do zderzenia  *)

(* wektor położenia punktowej masy *)

r1[t_]:=If[t<0,{v*t,L/2},{v11*Cos[θ]*t,L/2+v11*Sin[θ]*t}]

(* wektor położenia środka preta *)

r2[t_]:={0,0}

(* prędkość kątowa pręta wokół osi prostopadłej do płaszczyzny rysunku, przechodzącej przez środek pręta *)

omega[t_]:=If[t<0,0,ω1]

(* położenie górnego (przed obrotem) końca pręta *)

rA[t_]:=r2[t]+{L/2*Sin[omega[t]*t],L/2*Cos[omega[t]*t]};

(* położenie dolnego (przed obrotem) końca pręta *)

rB[t_]:=r2[t]-{L/2*Sin[omega[t]*t],L/2*Cos[omega[t]*t]};

pret[t_]:=Line[{rA[t],rB[t]}];

gpret[t_]:=Graphics[{Thick,Gray,pret[t]}]

masa[t_]=Disk[r1[t],1/20];

gmasa[t_]:=Graphics[masa[t]]

os=Disk[{0,0},1/40];

gos:=Graphics[{Red,os}];

Animate[Show[gmasa[t],gpret[t],gos,PlotRange->{{-2.1,4},{-0.6,2}},AspectRatio->Automatic],{t,t0,2}]

aaa=Table[Show[gmasa[t],gpret[t],gos,PlotRange->{{-2.1,4},{-0.6,2}},AspectRatio->Automatic],{t,t0,6,0.04}];

Export[
 NotebookDirectory[] <> "rod4.gif", aaa];