Przykład liczenia środka masy bryły przestrzennej
Środek masy wycinka jednorodnego odwróconego stożka o
 równaniu
x=ϱ*Cos[φ],
y=ϱ*Sin[φ],
z=z',
0< φ<α,
0 < ϱ < R,
(H/R)*ϱ<z'<H .

RegionPlot3D[z>2(Sqrt[x^2+y^2])&&y<=0,{x,-2,2},{y,-2,2},{z,0,4}]

ClearAll["Global`*"]

dVpodϱdφdzp=ϱ

(* To ma oznaczać, że we współrzędnych walcowych element objetości dV=ϱ*dϱ*dφ*dz' *)

x=ϱ*Cos[φ];

y=ϱ*Sin[φ];

z=zp;

Teraz można policzyć wszystkie całki analitycznie dla dowolnego α, przyjmując, że gęstość objętościowa masy ρ = (dm/dV) jest stała.

(* Całkowita masa *)

M=Simplify[Integrate[ρ*dVpodϱdφdzp,{φ,0,α},{ϱ,0,R},{zp,(H/R)*ϱ,H}]]

xcm=Simplify[Integrate[x*ρ*dVpodϱdφdzp,{φ,0,α},{ϱ,0,R},{zp,(H/R)*ϱ,H}]/M]

ycm=Simplify[Integrate[y*ρ*dVpodϱdφdzp,{φ,0,α},{ϱ,0,R},{zp,(H/R)*ϱ,H}]/M]

zcm=Simplify[Integrate[z*ρ*dVpodϱdφdzp,{φ,0,α},{ϱ,0,R},{zp,(H/R)*ϱ,H}]/M]

Widać, że dla α=2π dostajemy cały (odwrócony) stożek o promieniu R i wysokości H. W szczególności M/ρ daje objętość stożka !

V=(1/ρ)*M/.{α->2π}

xcm/.{α->2π}

ycm/.{α->2π}

zcm/.{α->2π}

Dla α=π dostajemy połowę (odwróconego) stożka o promieniu R i wysokości H. Stożek przecinamy płaszczyzną zawierającą oś symetrii stożka.

M/.{α->π}

xcm/.{α->π}

ycm/.{α->π}

zcm/.{α->π}