Przykład krzywej Lissajous

Ruch punktu materialnego dany jest układem równań
x = b sin ( ω t ),
y = c cos ( 2 ω t ),
gdzie b, c i ω to dodatnie stałe.
Zbadać, czy mamy do czynienia z ruchem okresowym.
Czy ruch jest ograniczony przestrzennie ?
Znaleźć równanie toru oraz podać  minimalną i maksymalną 
długość wektora prędkości.
Przykład:

b=5;c=2;ω=4π;p=ParametricPlot[{b Sin [ω t],c Cos [2 ω t]},{t,0,2π/ω},PlotRange->{{-11/2,11/2},{-5/2,5/2}},AxesLabel->{"x [m]","y [m]"},PlotLabel-> "b=5m, c=2m, ω=4π"];
 (* Export[ NotebookDirectory[] <> "przyklad.png",p];  *)

Animate[Show[p,ListPlot[{{b Sin [ω t],c Cos [2 ω t]}},PlotStyle->{PointSize[0.03],Orange}]],{t,0,2π/ω}]

ClearAll[b,c,ω];

(* wektor położenia w płaszczyźnie xy *)
r={b Sin [ω t],c Cos [2 ω t]};

(* wektor prędkości *)
v=D[r,t]

(* Rozważam kwadrat długości wektora prędkości, bo ekstrema tej funkcji są łatwiejsze do wyznaczenia *)
absv2=FullSimplify[v.v,b>0&&c>0&&ω>0]

(* pierwsza pochodna *)
dabsv2=FullSimplify[D[absv2,t],b>0&&c>0&&ω>0]

(* druga pochodna *)
ddabsv2=FullSimplify[D[dabsv2,t],b>0&&c>0&&ω>0]

(* 
W ogólnym przypadku nie jest łatwo znaleźć ekstremalne wartości (kwadratu) długości wektora prędkości. Dlatego ograniczymy się do naszego przykładu. Ze względu na okresowość ruchu, należy ograniczyć się do przedziału  0 ≤  t ≤ 2π/ω
*)

b=5;c=2;ω=4π;
s=Solve[dabsv2==0&&t≥ 0&&t≤2π/ω,t]

(* Wartości pierwiastków pierwszej pochodnej w formie listy *)
ekstrema=Simplify[t/.s]

(* Wartości przybliżone pierwiastków pierwszej pochodnej *)
N[ekstrema]

(* Wartości drugiej pochodnej w miejscach znikania pierwszej pochodnej *)Simplify[ddabsv2/.s]

(* Dlatego, pierwsze pięć wartości t w liście ekstrema to minima, a pozostałe to maksima.
Sprawdźmy to na wykresie ! *)

Plot[absv2,{t,0,2π/ω},AxesLabel->{"t [s]","|v((|)^2) [(m/s)^2]"},PlotLabel-> "b=5m, c=2m, ω=4π"]

(* Wartości samej funkcji (kwadratu długości wektora prędkości) w miejscach znikania pierwszej pochodnej, czyli wartości w ekstremach lokalnych *)Simplify[absv2/.s]

(* Wartości numeryczne *)
N[Simplify[absv2/.s]]